On 1/15/2022 12:42 PM, Verachten Bruno wrote:

OpenSCAD has basically nothing for extracting information from a
model.  If you know where two points are, you can do straightforward
arithmetic to get the distance between them... the problem is knowing
where the two points are.

https://github.com/revarbat/BOSL2/wiki/shapes3d.scad#module-ruler

Totally magic?  How would it know which dimensions you needed measured?

In case it's helpful, here are a couple of functions (and the random
utility functions that they depend on) that draw dimension arrows
between two specified points.  They're kind of specialized to my needs -
they measure in inches, and (per the "inch=1" at the top) believe that
OpenSCAD units are inches.  (Which they are, in the scale model that I
use these functions for.)  dim2() makes a two-dimensional dimension
arrow; dim3() makes a three-dimensional one.

inch = 1;

function default(val, def) = is_undef(val) ? def : val;
// Given an [x,y] or [x,y,z], transform to a
// [rho, theta] or [rho, theta, phi].
// Note that in mathematical spherical coordinates,
// phi is measured down from vertical.  This is as
// opposed to geographic coordinates, where latitude
// is measured up from the equator.
function topolar(p) =
    len(p) == 3 ? topolar3(p) : topolar2(p);

function topolar2(p) = [
    norm(p),
    atan2(p.y, p.x)
];

function topolar3(p) = [
    norm(p),
    atan2(p.y, p.x),
    atan2(norm([p.x,p.y]), p.z)
];

// @brief       Given an [x,y] or an [x,y,z], return an [x,y,z].
// @param   a   A two- or three- element array
// @returns     A three-element array
function make3(a) =
    assert(len(a) == 2 || len(a) == 3)
    len(a) == 3 ? a : concat(a, 0);
    
// @brief       Given an [x,y] or an [x,y,z], return an [x,y],
//              discarding z.
// @param   a   A two- or three- element array
// @returns     A two-element array
function make2(a) =
    assert(len(a) == 2 || len(a) == 3)
    [ a[0], a[1] ];

module trapezoid(h, w, w1, w2) {
    w1 = default(w1, w);
    w2 = default(w2, w);
    polygon([
        [-w1/2, 0],
        [-w2/2, h],
        [w2/2, h],
        [w1/2, 0]
    ]);
}

module dim3(a, b, rot=0, h=10, r, d=1, label) {
    a = make3(a);
    b = make3(b);
    r = default(r, default(d, 1)/2);
    d = default(d, r*2);
    p = topolar(b-a);
    label = default(label, str(round(p[0]/inch), "\""));
    cone_r = r*2;
    cone_h = r*4;
    translate(a) rotate([0,p[2],p[1]]) {
        translate([0,0,cone_h]) cylinder(h=p[0]-cone_h*2,r=r);
        translate([0,0,p[0]-cone_h]) cylinder(h=cone_h, r1=cone_r, r2=0);
        cylinder(h=cone_h, r1=0, r2=cone_r);
        rotate([0,-90,0])
            rotate([rot,0,0])
            linear_extrude(height=r*2, center=true)
            translate([p[0]/2,r*1.2,0])
            text(label, size=h, halign="center", valign="bottom");
    }
}

module dim2(a, b, h=10, r, d, label) {
    a = make2(a);
    b = make2(b);
    r = default(r, default(d, 1)/2);
    d = default(d, r*2);
    p = topolar(b-a);
    label = default(label, str(round(p[0]/inch), "\""));
    cone_r = r*3;
    cone_h = r*4;
    translate(a) rotate(p[1]) {
        translate([cone_h,-r]) square([p[0]-cone_h*2,d]);
        translate([p[0]-cone_h,0]) rotate(-90) trapezoid(h=cone_h, w1=cone_r*2, w2=0);
        rotate(-90) trapezoid(h=cone_h, w1=0, w2=cone_r*2);
        translate([p[0]/2,r*1.2])
            text(label, size=h, halign="center", valign="bottom");
    }
}

dim3([0,0,0], [100,100,100]);
dim2([0,0], [100,100]);

I measure features on other people's STLs with NetFabb studio.

On Sat, 15 Jan 2022 at 20:43, Verachten Bruno gounthar@gmail.com wrote:

You, I, many others have asked for measurement tools inside the interface,
but the participants of this list do not like this request.

I think there will not be any measurement tool, and in the end a move to
another program for some users  is basically unavoidable because of this
issue.

Edmund

On Sat, Jan 15, 2022 at 10:21 PM nop head nop.head@gmail.com wrote:

The bltouch dimensions and position requirements are here
https://www.antclabs.com/manual . All you need to do is work out where
you are going to fix the support bracket you design to the printer.
Mount it a bit higher and print some shims to position the blt at the
correct distance from the bed. The thingiverse item, is a poor design.
You need to access the small grub screw in the top of the blt, and it
does not look like it is genuine blt that is used.

On 15/01/2022 20:42, Verachten Bruno wrote:

On 1/15/2022 2:15 PM, edmund ronald wrote:

Nobody doesn't like the request.

Rather, nobody is willing to spend their time to make it happen.

Please feel free to implement it and submit the proposed change.

Do you se something like this when you F5 or F6 with unsaved changes?

Parsing design (AST generation)...

Saved backup file: C:/Users/MeB/Documents/OpenSCAD/backups/unsaved-backup-ncSSIhWS.scad

Also closing with unsaved changes should get:

Do you?

--
This email has been checked for viruses by AVG.
https://www.avg.com

One issue is that now if you use the customiser it marks the document as
changed, when it isn't, so I get used to ignoring those warnings as I never
save customiser settings.

On Sat, 15 Jan 2022 at 23:02, MichaelAtOz oz.at.michael@gmail.com wrote:

Not on Mac - there is the “*” in the file title - the problem arose because I opened the second file from finder which opens it in a separate window and not in a tab - so I had two windows open and not two tabs.

I went to OpenScad-> Quit Openscad on the active window which had no changes expecting it to quit that window and it quit both windows simultaneously without a save prompt for all of the changed data in the other window….

thanks
Bob.C