Native OpenSCAD includes the ability to place a cube based on a center point,
rather than based on one corner.  E.g.

*cube([10,10,10]);*

http://forum.openscad.org/file/t2397/Capture1.png

vs

*cube([10,10,10], center=true);*

http://forum.openscad.org/file/t2397/Capture2.png

I find, however, that I often need to center the cube in just one dimension,
for example y axis only.  Thus I sometimes write the following code to
extend cube centering functionality:
*
module cube2(size, center=[0,0,0]) {
translate([-(size.x/2)*center.x, -(size.y/2)*center.y,
-(size.z/2)*center.z])
cube(size);
}  *

Examples of use:

*TestSize = [10,10,10];
color("red") cube2(TestSize, center=[0,1,0]);
color("blue") cube2(TestSize, center=[1,0,1]);*

http://forum.openscad.org/file/t2397/Capture3.png

Feature request:
I would like to see this implemented into native OpenSCAD.  Thus the
center parameter would be overloaded as follows:
-- If a boolean (true / false) is passed, then it would work as previously.
-- if an expression that evaluates to 0, then interpreted as false, if any
other number, then as true.  (currently passing in "1" is interpreted as
false.)
-- if a vector ([1,1,1]) is passed, then each element is interpreted as
boolean for each dimension.  E.g. center.x would be parameter for centering
in x axis, and so on for .y and .z

I suspect this would be a relatively easy bit of code to implement.

Yes, I can just make my own custom library and include this for my own use.
But does anyone else think this would be a helpful addition to the native
language?

Thanks
Kevin T

--
Sent from: http://forum.openscad.org/

Kevin,What you're asking is the perfect example of feature creep. A feature that does not add any value to the existing code. If you really want it, create a module that will do what you want, and don't bloat a good feature with useless stuff.
Just my two cents,Jean-Paul N1JPL 

Sent from Yahoo Mail on Android

On Sun, Nov 29, 2020 at 11:36 AM, kdtopkdtop3@GMAIL.COM wrote:  Native OpenSCAD includes the ability to place a cube based on a center point,
rather than based on one corner.  E.g.

    cube([10,10,10]);

http://forum.openscad.org/file/t2397/Capture1.png

vs

    cube([10,10,10], center=true);

http://forum.openscad.org/file/t2397/Capture2.png

I find, however, that I often need to center the cube in just one dimension,
for example y axis only.  Thus I sometimes write the following code to
extend cube centering functionality:
*
    module cube2(size, center=[0,0,0]) {
      translate([-(size.x/2)*center.x, -(size.y/2)*center.y,
-(size.z/2)*center.z])
        cube(size);
    }  *

Examples of use:

    TestSize = [10,10,10];
    color("red") cube2(TestSize, center=[0,1,0]);
    color("blue") cube2(TestSize, center=[1,0,1]);

http://forum.openscad.org/file/t2397/Capture3.png

Feature request:
  I would like to see this implemented into native OpenSCAD.  Thus the
center parameter would be overloaded as follows:
-- If a boolean (true / false) is passed, then it would work as previously. 
-- if an expression that evaluates to 0, then interpreted as false, if any
other number, then as true.  (currently passing in "1" is interpreted as
false.)
-- if a vector ([1,1,1]) is passed, then each element is interpreted as
boolean for each dimension.  E.g. center.x would be parameter for centering
in x axis, and so on for .y and .z

I suspect this would be a relatively easy bit of code to implement.

Yes, I can just make my own custom library and include this for my own use.
But does anyone else think this would be a helpful addition to the native
language?

Thanks
Kevin T

--
Sent from: http://forum.openscad.org/

OpenSCAD mailing list
Discuss@lists.openscad.org
http://lists.openscad.org/mailman/listinfo/discuss_lists.openscad.org

I just made my own cube module, which has three extra arguments, xalign,
yalign and zalign. If they are 0, it's centered, if -1, the bottom (or, more
precisely, the negative side) aligns with the axis, if 1, the top (the
positive side) aligns with the axis.

Literally a 5 minute job to make.

I don't see a need for this in the core language.

--
Sent from: http://forum.openscad.org/

I have a module jcube (for justified cube) that takes dims and a
[jz,jy,jz] justify vector where -1 means the cube goes negative from the
origin, 0 means centered, and +1 means positive from the origin.

It's based on a more general justify module that similarly justifies its
children.  It takes a bounding box (either [dx,dy,dz] dimensions with an
implied origin at [0,0,0], or [[ox,oy,oz], [dx,dy,dz]]) and a justify
vector as above.

Both also take a simple boolean center equivalent to j=[0,0,0], but I
don't know if I've ever used it since it's longer.

With respect to whether such a feature should be in the base... undecided.

It could certainly be in MCAD and so available in every installation.

Argument for putting it in the base:  so you don't have to have a module
that is almost, but not quite, the same as "cube".  Also helps to
establish a convention for how to represent this sort of justification,
so that it's obvious how justifying a cylinder, or sphere, or whatever
would work.

Argument against:  it doesn't need to be.  (But note:  "center" doesn't
need to be either, so we aren't strictly minimal.)

use <default.scad>

// @brief       Given an [x,y] or an [x,y,z], return an [x,y,z].
// @param   a   A two- or three- element array
// @returns     A three-element array
function make3(a) =
    assert(len(a) == 2 || len(a) == 3)
    len(a) == 3 ? a : concat(a, 0);
    
// @brief        Justify children as specified by argument.
// @param center Equivalent to justify=[0,0,0].
// @param j      [jx,jy,jz]:
//                   +1 toward-positive
//                    0 center
//                   -1 toward-negative
// @param bb     Bounding box:
//                   [dimx,dimy,dimz]
//                   [ [ox,oy,oz], [dimx,dimy,dimz] ]
// @children     Object(s) to be justified.
// @note Works for two- or three- dimensional objects.
// @note If more than one object is supplied as a child, they
//       are all justified en mass with respect to the specified
//       bounding box.
module justify(center, j, bb) {
    origin = make3(
        assert(is_list(bb))
        is_list(bb[0])
            ? assert(len(bb) == 2) bb[0]
            : [0,0,0]
    );
    dims = make3(
            is_list(bb[0])
                ? bb[1]
                : bb
    );
    j = make3(default(j, center ? [0,0,0] : [1,1,1]));
    function o(flag, dim) = flag > 0 ? 0 :
        flag < 0 ? -dim :
        -dim/2;
    translate([o(j[0], dims[0]),
        o(j[1], dims[1]),
        o(j[2], dims[2])])
        translate(-origin)  // Move BB minima to [0,0,0]
        children();
}


// @brief        A justified cube
// @param dims   Dimensions of the cube
// @param center Equivalent to j=[0,0,0]
// @param j      As for justify() above
module jcube(dims, center, j) {
    justify(center=center, j=j, bb=dims) cube(dims);
}

// Test/demos
for (xj=[-1:1], yj=[-1:1], zj=[-1:1]) {
    justify(j=[xj,yj,zj], bb=[[-10,-10,-10],[20,20,20]])
        color([(xj+1)/2, (yj+1)/2, (zj+1)/2]) sphere(r=10);
}

translate([30,0]) for (xj=[-1:1], yj=[-1:1]) {
    justify(j=[xj,yj], bb=[[-10,-10],[10,10]])
        color([(xj+1)/2, (yj+1)/2, 0]) circle(r=10);
}

It depends on a trivial function "default":

function default(val, def) = is_undef(val) ? def : val;