Back when I was doing woodworking, using a scrollsaw, I would cut 3D
keychains with 2 words (usually first and last name).  Basically you start
out with a length of wood that is the same depth and height and tape a
pattern of the words on the top and face of the block and cut out the wood
AROUND the letters -- examples  here
https://www.youtube.com/watch?v=6tvOxHixwoo  and  here
http://www.scrollbench.com/2011/02/using-scroll-saw-workshops-keychain.html
.
Since I got my 3D printer I've been wanting to recreate these in plastic.
I can sort of SIMULATE the result of cutting the first word by creating a
rectangle, cutting out a smaller version of the block and then putting in
the text and extruding it:

----------8<---Cut-Here---8<----------
fName="FNAME";
lName="LNAME";
height=10;

difference() {
cube([44,height,height]);
translate([1,-1,1]) cube([42,52,height-2]);
}

translate([1.5,10,1])
rotate(90,[1,0,0])
linear_extrude(height)
text(lName,8.5);
----------8<---Cut-Here---8<----------
http://forum.openscad.org/file/t3003/lname_block.png
But then I'm stuck, as I can't do that again for the 2nd word from the top.
What I REALLY need is a way to cut out the whitespace around the letters.
Does anyone have any ideas of how to do this?
The other problem is trying to figure out how long to make the block based
on the size of the text/font...
... Billy ...

--
Sent from: http://forum.openscad.org/

fname="BARB";
lname="WALLS";

height = 1;
length = 5;
margin = .1;
sf = 20;

module cutcubes(){
cube([length - margin2, height - margin2, height + .02], center=true);
}

module cutcubec(){
cube([length - margin2, height - margin2, height - margin*2 ],
center=true);
}

module cutname(name){
difference(){
difference(){
union(){
difference(){
cube([length, height, height], center=true);
cutcubes();
}
translate([0, 0, -height/2])
linear_extrude(height, convexity=2)
text(name, height - margin, valign="center", halign="center");
}
cutcubec();
}
rotate(90, [1, 0, 0])
cutcubes();
}
}

scale(sf){
cutname(fname);
rotate(90, [1, 0, 0])
cutname(lname);
}

--
Sent from: http://forum.openscad.org/

The general answer is probably intersection():

fName="FNAME";
lName="LNAME";
height=10;

intersection() {
linear_extrude(height, center = true, convexity = 3)
text(fName,height, font="Courier New:style=Bold", halign="center", valign="center");

rotate([90, 0, 0])
linear_extrude(height, center = true, convexity = 3)
text(lName,height, font="Courier New:style=Bold", halign="center", valign="center");
}

I suspect that works best with a bold mono-spaced font.

(See also File->Examples->Advanced->GEB for a 3 axis version)

ciao,
Torsten.

$fn = 50;
fname="BARB";
lname="WALLS";

height = 1;
length = 5;
margin = .1;
sf = 20;

module stock(){
hl = (length - 1)/2;
cube([length - 1, height, height], center=true);
translate([-hl, 0, 0])
cylinder(height, d=height, center=true);
translate([hl, 0, 0])
cylinder(height, d=height, center=true);
}

module cutstock(){
hl = (length - 1)/2;
cube([length - 1, height - margin2, height + .02], center=true);
translate([-hl, 0, 0])
cylinder(height + .02, d=height-margin2, center=true);
translate([hl, 0, 0])
cylinder(height + .02, d=height-margin*2, center=true);
}

module case(){
difference(){
stock();
cutstock();
}
}

module cutname(name){
case();
translate([0, 0, -height/2])
linear_extrude(height, convexity=2)
text(name, height - margin, valign="center", halign="center");
}

scale(sf){
intersection(){
cutname(fname);
rotate(90, [1, 0, 0])
cutname(lname);
}
}

/*
I like that this enables rounding the ends, but I'm not so sure I like the
messy internals even though that's probably what the sawn version looks
like.
*/

--
Sent from: http://forum.openscad.org/

But it's easy to ream out the center in cutname() using a modified
cutcubec().

--
Sent from: http://forum.openscad.org/

This is comparable to creating an ambigram, although on two different axes
from the tutorial I found.
This  tutorial https://www.youtube.com/watch?v=baO1-HSodIs  uses Fusion
360 to create text in two planes by intersection, just as with the samples
of code provided in the posts here. The video is 26 minutes long.

I've used it with the hobbyist version of F360 and it works great, resulting
in a number of 3D printed gifts to friends and family.

I had often suspected that the same concepts could be applied to OpenSCAD.
One aspect of this process is that the text is "collected" along a diagonal
and joined to a base, rather than enclosed in a cage.

--
Sent from: http://forum.openscad.org/

WOW!  I was really only looking for some pointers, not expecting a complete
solution!  Thank you!  Now I just need to figure out what you've done...  I
printed one out already -- not sure what's up with the stringing -- might
have do do some tuning to the printer or something, but other than that,
pretty good!  Thanks again!

http://forum.openscad.org/file/t3003/3d_keychain_barb_ward_480x222.jpg

--
Sent from: http://forum.openscad.org/