In BOSL2, many of the modules that create multiple copies of children set $
variables so that your children can vary their behavior.  Consider this
example:

include<BOSL2/std.scad>
xcopies(n=10,spacing=10)  union(){
mytext = str($idx);
text(mytext);
}

It prints the ten digits spread out on the X axis.  But why do I have
"union()" in there?  The reason is that if I remove the union, the code
fails.

WARNING: Ignoring unknown variable '$idx' in file test9.scad, line 20
<20,/home/adrian/scad/test9.scad>

<20,/home/adrian/scad/test9.scad>That's strange. Why is $idx unknown? You
can obviously simplify this to

xcopies(n=10,spacing=10)
text(str($idx));

and this version also fails! The simplest obvious scheme tells me that $idx
is undefined. So what's the magic of union?

Another way to fail is to try to assign to a $ variable:

xcopies(n=10,spacing=10) {
$mytext = str($idx);
text($mytext);
}

And another way to succeed is to use let:

xcopies(n=10,spacing=10)
let(mytext = str($idx))
text(mytext);

And this also works:

xcopies(n=10,spacing=10)
echo(sin($idx));

So what's going on here?

I think this is probably the relevant test program:

module foo() {
    a = echo("foo assignments") 0;
    echo("foo modules");
    children();
}

c = echo("top level assignments") 0;
echo("top level modules");

foo() {
    b = echo("child assignments");
    echo("child modules");
}

In 2021.01 that produces:

ECHO: "top level assignments"
ECHO: "top level modules"
ECHO: "child assignments"
ECHO: "foo assignments"
ECHO: "foo modules"
ECHO: "child modules" 

That makes the behavior that you observe totally obvious:  the child
assignments are executed before anything in foo itself is executed.

In a more or less current development tip, the result is:

ECHO: "top level assignments"
ECHO: "top level modules"
ECHO: "foo assignments"
ECHO: "foo modules"
ECHO: "child assignments"
ECHO: "child modules"

Other special cases:

In 2021.01, the child assignments are evaluated exactly once, whether or
not foo calls children().  Kind of unsurprising, since they are
evaluated before anything in foo is evaluated.

In the development tip, child assignments are evaluated once for each
call to children().  Note that this includes zero times if foo never
calls children().

In all versions, all assignments are evaluated before all module calls.

The development tip behavior does seem better, except that multiple
evaluations of the child assignments may be redundant - and, if they
include randomness, may be inconsistent.  (Which means that it wasn't a
strictly compatible change.)

I don't know what the rationale was for the change.  I could research it
if somebody really wanted to know.

For super extra fun, I realized that I should compare when arguments and
defaults were executed.

a = echo("top level assignments");
echo("top level modules");

module foo(arg1 = echo("foo defaults 1") 0, arg2 = echo("foo defaults 2") 0) {
    b = echo("foo assignments");
    echo("foo modules");
    children();
}

foo(echo("top level arguments") 0) {
    c = echo("child assignments") 0;
    echo("child modules");
}

2021.01 says:

ECHO: "top level assignments"
ECHO: "top level modules"
ECHO: "child assignments"
ECHO: "foo defaults 1"
ECHO: "foo defaults 2"
ECHO: "top level arguments"
ECHO: "foo assignments"
ECHO: "foo modules"
ECHO: "child modules"

so note that the defaults are evaluated before the arguments, which
necessarily means that defaults are evaluated and then discarded if the
argument is supplied.

The development tip is more sensible:

ECHO: "top level assignments"
ECHO: "top level modules"
ECHO: "top level arguments"
ECHO: "foo defaults 2"
ECHO: "foo assignments"
ECHO: "foo modules"
ECHO: "child assignments"
ECHO: "child modules"

Note that defaults are evaluated after arguments, and not evaluated if
unused.

The fun just never stops.

module foo(x = echo("defaults") $y) {
    echo(x);
}

$y = 1;
foo($y = echo("arguments") 2);

In 2021.01:

ECHO: "defaults"
ECHO: "arguments"
ECHO: 1

Not what you might want, but unsurprising given the previous results.

In the development tip, drum roll please...

ECHO: "arguments"
ECHO: "defaults"
ECHO: 1