On 12/20/2015 04:24 PM, fred_dot_u wrote:

One option would be to use a module that generates both the x and -x
child module:

$fn=120;
high=1;
dia=1.25;

module mirrored_translate(x) {
translate([x, 0, 0]) children();
if (x > 0.001) translate([-x, 0, 0]) children();
}

for (i=[0:1:5])
mirrored_translate(i*1.25)
cylinder(high,d=dia);

Note that your code generated 2 identical overlapping cylinders at
the center which can cause issues later on.

ciao,
Torsten.

On Sun, Dec 20, 2015 at 8:34 AM, Torsten Paul Torsten.Paul@gmx.de wrote:

or simply, without using the module, (although that is coolness), just put
braces around what you want in your for loop (to form a block), as in:

for (i=[0:1:5]) {
translate([i*(1.25), 0, 0])
cylinder(high,d=dia);
translate([-(i*1.25), 0, 0])
cylinder(high,d=dia);
}

--
Extra Ham Operator: K7AZJ
Registered Linux User: 275424
Raspberry Pi and Arduino developer

The most exciting phrase to hear in science - the one that heralds new
discoveries - is not "Eureka!" but "That's funny...".- Isaac. Asimov

I
*f you give someone a program, you will frustrate them for a day; if you
teach them how to program, you will frustrate them for a lifetime. *-
Anonymous

If writing good code requires very little comments, then writing really
excellent code requires no comments at all!- Ken Thompson

On 12/20/2015 06:32 PM, fred_dot_u wrote:

Try to forget programming for a bit :-). Just think real
objects and lets define recipes how to create those...

So we have a red cube of size 10 - in OpenSCAD that's:

color("red") cube(10, center = true);

Now we introduce modules which are basically just a shortcut
for what's inside:

module red_cube() {
color("red") cube(10, center = true);
}

red_cube();

We simply gave the recipe to produce a red cube a special name
using the module definition which by itself does nothing. But
we do can use the "red_cube()" now which creates the object we
defined in that recipe.

Then there's modules that can affect other things, for example
translate() which moves it's child objects.

translate([20, 20, 0]) red_cube();

Simply moving that into a module, for example with a single
parameter for the x part of the translation gives a recipe
for a red_cube() that can be moved in x direction using the
x parameter for the recipe (so we have to give that parameter
when using the recipe):

module my_translate(x) {
translate([x, 20, 0]) red_cube();
}

my_translate(x = 20);

Now using the special children() module we can substitute the
object that is translated and leave that for later, similar to
the built-in translate(). Effectively that children() will be
now replaced with whatever is written after the actual use of
my_translate() - e.g. once the red_cube() and once a "normal"
cube().
So basically we leave the part that describes the translation
in the my_translate() module but don't force it to be applied
only to red_cube(). Now it can be applied to any child object.

module my_translate(x) {
translate([x, 20, 0]) children();
}

my_translate(x = 20) red_cube();
my_translate(x = -20) sphere(5);

Some more examples:
http://files.openscad.org/examples/Basics/children.html
http://files.openscad.org/examples/Basics/children_indexed.html

ciao,
Torsten.

I've collected the resources you've provided and am going to have to ponder for a while, experiment and attempt to understand clearly the mechanics of the children() feature. Would it be practical to create a short bit of code in "longhand" that represents what the children() feature performs? I'm nearing the end of my 60th year, having started my life in my zero-th year, so the brain cells don't function well later in the day. If the earlier part of the day involves strenuous activity, the brain cells are also kaput for the day.

On Sunday, December 20, 2015 3:40 PM, Torsten Paul <Torsten.Paul@gmx.de> wrote:

On 12/20/2015 06:32 PM, fred_dot_u wrote:

Try to forget programming for a bit :-). Just think real
objects and lets define recipes how to create those...

So we have a red cube of size 10 - in OpenSCAD that's:

  color("red") cube(10, center = true);

Now we introduce modules which are basically just a shortcut
for what's inside:

  module red_cube() {
    color("red") cube(10, center = true);
  }

  red_cube();

We simply gave the recipe to produce a red cube a special name
using the module definition which by itself does nothing. But
we do can use the "red_cube()" now which creates the object we
defined in that recipe.

Then there's modules that can affect other things, for example
translate() which moves it's child objects.

  translate([20, 20, 0]) red_cube();

Simply moving that into a module, for example with a single
parameter for the x part of the translation gives a recipe
for a red_cube() that can be moved in x direction using the
x parameter for the recipe (so we have to give that parameter
when using the recipe):

  module my_translate(x) {
    translate([x, 20, 0]) red_cube();
  }

  my_translate(x = 20);

Now using the special children() module we can substitute the
object that is translated and leave that for later, similar to
the built-in translate(). Effectively that children() will be
now replaced with whatever is written after the actual use of
my_translate() - e.g. once the red_cube() and once a "normal"
cube().
So basically we leave the part that describes the translation
in the my_translate() module but don't force it to be applied
only to red_cube(). Now it can be applied to any child object.

  module my_translate(x) {
    translate([x, 20, 0]) children();
  }

  my_translate(x = 20) red_cube();
  my_translate(x = -20) sphere(5);

Some more examples:
http://files.openscad.org/examples/Basics/children.html
http://files.openscad.org/examples/Basics/children_indexed.html

ciao,
  Torsten.

OpenSCAD mailing list
Discuss@lists.openscad.org
http://lists.openscad.org/mailman/listinfo/discuss_lists.openscad.org

There isn't a long hand version of children(), you simple can't do what it
does any other way. The children of a module are the modules below it in
the tree. For example the children of translate are the things you place
after it that you want translated. The children() module gets replaced by
all the children of the module it is contained in. For example:

module rotate90() {
rotate([0, 0, 90])
children();
}

rotate90()
cube([1,10,1]);

Becomes: -

rotate([0, 0, 90])
cube([1, 10, 1]);

In this case there is only one child but if you enclose several things in
braces you can have multiple children() and you can use children(0) to
refer to the first one, children(1) the second and so on.

On 21 December 2015 at 21:46, fred fred_dot_u@yahoo.com wrote: