use <sweep.scad>
use <scad-utils/transformations.scad>
use <scad-utils/shapes.scad>

/* 
Sweep with easing equations.

Based on sweep demo from:
https://github.com/openscad/list-comprehension-demos/blob/master/sweep-test.scad

First implementation with Robert Penner's easing equations (t:current time, b:beginning value, c:change in value, d:duration)
http://robertpenner.com/easing/penner_easing_as1.txt

Now only with 0<k<1 as in:
https://github.com/tweenjs/tween.js/blob/master/src/Tween.js

*/

bottom_w = 12;
top_w = 3;
height = 12;
steps = 60;
straight_l = 30;


margin = 10;
spacing = max(bottom_w + margin, top_w + margin);
pathstep = height/steps;
delt = top_w - bottom_w;

square_points = square(1);
shape_points = circle(r=0.5, $fn=60);
//triangle_points = [[1, 0], [-0.5, sqrt(3)/2], [-0.5, -sqrt(3)/2]];


// Sinusoidal
translate([0, 2*spacing, 0]) {
	translate([-spacing,    0, 0]) sweep(shape_points, path_inSinus);
	translate([0,           0, 0]) sweep(shape_points, path_inOutSinus);
	translate([spacing,     0, 0]) sweep(shape_points, path_outSinus);
	translate([spacing*1.5, 0, 0]) color("grey") text(text="Sinusoidal", size=5, valign="center");
}

// Circular
translate([0, spacing, 0]) {
	translate([-spacing,    0, 0]) sweep(shape_points, path_inCirc);
	translate([0,           0, 0]) sweep(shape_points, path_inOutCirc);
	translate([spacing,     0, 0]) sweep(shape_points, path_outCirc);
	translate([spacing*1.5, 0, 0]) color("grey") text(text="Circular", size=5, valign="center");
}

// Quadratic
translate([-spacing,    0, 0]) sweep(shape_points, path_inQuad);
translate([0,           0, 0]) sweep(shape_points, path_inOutQuad);
translate([spacing,     0, 0]) sweep(shape_points, path_outQuad);
translate([spacing*1.5, 0, 0]) color("grey") text(text="Quadratic", size=5, valign="center");

// Cubic
translate([0, -spacing, 0]) {
	translate([-spacing,    0, 0]) sweep(shape_points, path_inCubic);
	translate([0,           0, 0]) sweep(shape_points, path_inOutCubic);
	translate([spacing,     0, 0]) sweep(shape_points, path_outCubic);
	translate([spacing*1.5, 0, 0]) color("grey") text(text="Cubic", size=5, valign="center");
}

// Square - Cubic
translate([0, -2*spacing,   0]) {
	translate([-spacing,    0, 0]) sweep(square_points, path_inCubic);
	translate([0,           0, 0]) sweep(square_points, path_inOutCubic);
	translate([spacing,     0, 0]) sweep(square_points, path_outCubic);
	translate([spacing*1.5, 0, 0]) color("grey") text(text="Cubic", size=5, valign="center");
}


// Airfoil - Cubic
translate([0, -3*spacing, 0]) {
	translate([-spacing,    0, 0]) sweep(airfoil_points, path_inCubic);
	translate([0,           0, 0]) sweep(airfoil_points, path_inOutCubic);
	translate([spacing,     0, 0]) sweep(airfoil_points, path_outCubic);
	translate([spacing*1.5, 0, 0]) color("grey") text(text="Cubic", size=5, valign="center");
}
color("red")
translate([spacing, -4*spacing, 0]) {
	sweep(airfoil_points, path_outCubic);
	translate([0, 0, height - 0.01])
		straight_airfoil();
}

color("green")
translate([spacing, -5*spacing, 0]) {
	sweep(airfoil_points, path_fillet);
	translate([0, 0, height - 0.01])
		straight_airfoil();
}

	translate([-spacing, -5.5*spacing, 0]) color("lightgrey") text(text="in", size=4, halign="center");
	translate([0,        -5.5*spacing, 0]) color("lightgrey") text(text="in/out", size=4, halign="center");
	translate([spacing,  -5.5*spacing, 0]) color("lightgrey") text(text="out", size=4, halign="center");

//---------------------------------------------------------------------
path_inCirc = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inCirc(i/steps), bottom_w + delt*inCirc(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_outCirc = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*outCirc(i/steps), bottom_w + delt*outCirc(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_inOutCirc = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inOutCirc(i/steps), bottom_w + delt*inOutCirc(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_inQuad = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inQuad(i/steps), bottom_w + delt*inQuad(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_outQuad = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*outQuad(i/steps), bottom_w + delt*outQuad(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_inOutQuad = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inOutQuad(i/steps), bottom_w + delt*inOutQuad(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_inCubic = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inCubic(i/steps), bottom_w + delt*inCubic(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_inOutCubic = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inOutCubic(i/steps), bottom_w + delt*inOutCubic(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_outCubic = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*outCubic(i/steps), bottom_w + delt*outCubic(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_inSinus = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inSinus(i/steps), bottom_w + delt*inSinus(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_outSinus = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*outSinus(i/steps), bottom_w + delt*outSinus(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_inOutSinus = [ for (i=[0:steps]) 
	translation([0,0,i*height/steps]) * 
	scaling([bottom_w + delt*inOutSinus(i/steps), bottom_w + delt*inOutSinus(i/steps), 1]) * 
	rotation([0,0,0]) ];

path_fillet = [for(i=[0:steps]) 
    translation([0,0,height*i*i/steps/steps])*
    scaling([bottom_w+delt*fillet(i/steps),bottom_w+delt*fillet(i/steps),1])];

path_straight = [ for (i=[0:steps]) 
	translation([0,0,i*straight_l/steps]) * 
	scaling([top_w, top_w, 1]) * 
	rotation([0,0,0]) ];


//---------------------------------------------------------------------

//http://m-selig.ae.illinois.edu/ads/coord/ah93w257.dat

airfoil = [ [1.00000, 0.00029], [0.99893, 0.00062], [0.99572, 0.00162], [0.99039, 0.00325], [0.98296, 0.00528], [0.97347, 0.00777], [0.96194, 0.01050], [0.94844, 0.01349], [0.93301, 0.01683], [0.91573, 0.02050], [0.89668, 0.02455], [0.87592, 0.02899], [0.85355, 0.03388], [0.82967, 0.03921], [0.80438, 0.04499], [0.77779, 0.05121], [0.75000, 0.05783], [0.72114, 0.06479], [0.69134, 0.07203], [0.66072, 0.07947], [0.62941, 0.08702], [0.59755, 0.09461], [0.56526, 0.10209], [0.53270, 0.10928], [0.50000, 0.11592], [0.46730, 0.12168], [0.43474, 0.12630], [0.40245, 0.12957], [0.37059, 0.13139], [0.33928, 0.13177], [0.30866, 0.13075], [0.27886, 0.12842], [0.25000, 0.12490], [0.22221, 0.12032], [0.19562, 0.11481], [0.17033, 0.10849], [0.14645, 0.10148], [0.12408, 0.09387], [0.10332, 0.08575], [0.08427, 0.07724], [0.06699, 0.06843], [0.05156, 0.05942], [0.03806, 0.05035], [0.02653, 0.04133], [0.01704, 0.03254], [0.00961, 0.02407], [0.00428, 0.01610], [0.00107, 0.00840], [0.00000, 0.00000], [0.00107, -0.01027], [0.00428, -0.02084], [0.00961, -0.03119], [0.01704, -0.04116], [0.02653, -0.05117], [0.03806, -0.06075], [0.05156, -0.06981], [0.06699, -0.07847], [0.08427, -0.08673], [0.10332, -0.09454], [0.12408, -0.10181], [0.14645, -0.10837], [0.17033, -0.11406], [0.19562, -0.11874], [0.22221, -0.12233], [0.25000, -0.12480], [0.27886, -0.12604], [0.30866, -0.12599], [0.33928, -0.12461], [0.37059, -0.12194], [0.40245, -0.11799], [0.43474, -0.11277], [0.46730, -0.10623], [0.50000, -0.09842], [0.53270, -0.08953], [0.56526, -0.07980], [0.59755, -0.06953], [0.62941, -0.05910], [0.66072, -0.04886], [0.69134, -0.03913], [0.72114, -0.03020], [0.75000, -0.02226], [0.77779, -0.01550], [0.80438, -0.01006], [0.82967, -0.00594], [0.85355, -0.00303], [0.87592, -0.00123], [0.89668, -0.00038], [0.91573, -0.00035], [0.93301, -0.00096], [0.94844, -0.00201], [0.96194, -0.00337], [0.97347, -0.00480], [0.98296, -0.00601], [0.99039, -0.00696], [0.99572, -0.00728], [0.99893, -0.00739], [1.00000, -0.00744] ];

airfoil_points = transform(translation([-0.5, 0, 0]), airfoil);

module straight_airfoil() {
	sweep(airfoil_points, path_straight);
}





//---------------------------------------------------------------------
function inQuad(k)    = k*k;
function outQuad(k)   = k*(2-k);
function inOutQuad(k) = k < 0.5 ?  
                        0.5*pow(2*k, 2) : 
						-0.5 * (((2*k)-1) * (((2*k)-1) - 2) - 1);

function inCubic(k)    = k*k*k;
function outCubic(k)   = pow(k-1, 3)+1;
function inOutCubic(k) = k < 0.5 ?  
                         0.5*pow(2*k, 3) : 
						 0.5*(pow(2*k-2, 3) + 2);

function inCirc(k)    = 1 - sqrt(1 - k*k);
function outCirc(k)   = sqrt(1 - ((k-1) * (k-1)));
function inOutCirc(k) = k < 0.5 ? 
                        - 0.5* (sqrt(1-(2*k)*(2*k)) -1) : 
						  0.5 * (sqrt(1 - (2*k-2) * (2*k-2)) + 1);

function inSinus(k)    = 1 - cos(toDeg(k*PI/2));
function outSinus(k)   = sin(toDeg(k*PI/2));
function inOutSinus(k) = 0.5 * (1 - cos(toDeg(PI*k)));

function fillet(k)     = k*sqrt(2-k*k);

function toDeg(a) = a*180/PI;
//---------------------------------------------------------------------